#triangle3.bas
new
10 b$="1": rem b$ = Board ID
20 rem s = Servo number
30 rem p = Servo position
50 open "com1:", 9600 as #5
100 rem cycle thru motors @ stop
110 gosub 1200: rem stop servos
150 gosub 1000: rem wait
200 rem move forward
210 s = 2: p = 255: rem servo 2 reverse
220 gosub 1100: rem servo position
230 s = 3: p = 1: rem servo 3 forward
240 gosub 1100: rem servo position
250 gosub 1000: rem wait
260 gosub 1200: rem stop servos
270 gosub 1000: rem wait
300 rem sideways - left/down
310 s = 1: p = 255: rem servo 1 forward
320 gosub 1100: rem servo position
330 s = 2: p = 1: rem servo 2 reverse
340 gosub 1100: rem servo position
350 gosub 1000: rem wait
360 gosub 1200: rem stop servos
370 gosub 1000: rem wait
400 rem sideways - right/down
410 s = 1: p = 1: rem servo 1 reverse
420 gosub 1100
430 s = 3: p = 255: rem servo 3 forward
440 gosub 1100: rem servo position
450 gosub 1000: rem wait
460 gosub 1200: rem stop servos
500 goto 2000: rem close & end
1000 rem wait subroutine
1010 for w=1 to 5000: next w:
1020 return
1100 rem servo position subroutine
1110 print #5, "BD" + b$ + "SV" + str$(s) + "M" + str$(p)
1150 return
1200 rem all motors stop
1210 p = 0: rem servo stop
1220 for s=1 to 3: gosub 1100: next s
1230 return
2000 close #5: end
run